=begin pod

=TITLE class Channel

=SUBTITLE Thread-safe queue for sending values from producers to consumers

    class Channel { ... }

A C<Channel> is a thread-safe queue that helps you to send a series of objects from
one or more producers to one or more consumers.  Each object will arrive at only
one such consumer, selected by the scheduler.  If there is only one consumer
and one producer, order of objects is guaranteed to be preserved.  Sending on a
C<Channel> is non-blocking.

    my $c = Channel.new;
    await (^10).map: {
        start {
            my $r = rand;
            sleep $r;
            $c.send($r);
        }
    }
    $c.close;
    say $c.list;

Further examples can be found in the L<concurrency page|/language/concurrency#Channels>

=head1 Methods

=head2 method send

Defined as:

    method send(Channel:D: \item)

Usage:

    CHANNEL.send(ITEM)

Enqueues an item into the C<Channel>. Throws an exception of type
L<X::Channel::SendOnClosed> if the channel has been closed already.
This call will B<not> block waiting for a consumer to take the object.
There is no set limit on the number of items that may be queued, so
care should be taken to prevent runaway queueing.

=head2 method receive

Defined as:

    method receive(Channel:D:)

Usage:

   CHANNEL.receive

Receives and removes an item from the channel. It blocks if no item is
present, waiting for a C<send> from another thread.

Throws an exception of
type L<X::Channel::ReceiveOnClosed> if the channel has been closed, and the
last item has been removed already, or if C<close> is called while C<receive>
is waiting for an item to arrive.

If the channel has been marked as erratic with method C<fail>, and the last
item has been removed, throws the argument that was given to C<fail> as an
exception.

See method C<poll> for a non-blocking version that won't throw exceptions.

=head2 method poll

Defined as:

    method poll(Channel:D:)

Usage:

    CHANNEL.poll

Receives and removes an item from the channel. If no item is present, returns
C<Nil> instead of waiting.

See method C<receive> for a blocking version that properly responds to channel
closing and failure.

=head2 method close

Defined as:

    method close(Channel:D:)

Usage:

    CHANNEL.close

Close the C<Channel>, normally.  This makes subsequent C<send> calls die with
L<X::Channel::SendOnClosed>.  Subsequent calls of C<.receive> may still drain
any remaining items that were previously sent, but if the queue is empty, will
throw an L<X::Channel::ReceiveOnClosed> exception.  A C<Seq> produced by an
C<@()> or by the C<.list> method will not terminate until this has been done.

=head2 method list

Defined as:

    method list(Channel:D:) returns List:D

Usage:

    CHANNEL.list

Returns a C<Seq> which will iterate items in the queue and removes each item
from the queue as it iterates. This can only terminate once the C<close> method
has been called.

=head2 method closed

Defined as:

    method closed(Channel:D:) returns Promise:D

Usage:

    CHANNEL.closed

Returns a promise that will be kept once the channel is closed by a call to
method C<close>.

=head2 method fail

Defined as:

    method fail(Channel:D: $error)

Usage:

    CHANNEL.fail

Closes the C<Channel> (that is, makes subsequent C<send> calls die), and enqueues
the error to be thrown as the final element in the channel. Method C<receive>
will throw that error as an exception.  Does nothing if the channel has already
been closed or C<.fail> has already been called on it.

=head2 method Supply

Defined as:

	method Supply(Channel:D:)

Usage:

	CHANNEL.Supply

This returns an C<on-demand> L<Supply|Supply> that emits a value for every value 
received on the Channel. C<done> will be called on the C<Supply> when the L<Channel>
is closed.

Multiple calls to this method produce multiple instances of Supply, which compete
over the values from the Channel.

=head2 sub await

Defined as:

    multi sub await(Channel:D)
    multi sub await(*@)

Usage:

    await(CHANNEL)
    await(CHANNELS)

Waits until all of one or more channels has a value available, and returns
those values (it calls C<.receive> on the channel). Also works with
L<promises|/type/Promise>.

=end pod
